Ah, interruptions. These days, when the phone rings or someone butts in, I hit the F13 key on my Mac. If music is playing, iTunes smoothly fades it down to silence and pauses itself. After the coast is clear, I hit F13 again and the Mac asks what volume I’d like playback to resume at. Hit Return and the music fades back up. The effect is more pleasing than simply stabbing the Mute key, and it means I don’t lose my place. Further, being able to enter a volume directly is often nicer than messing with the volume up/down keys.
Launch the script when iTunes is playing, and you’re prompted to enter a new volume level. The default is 0, creating a fadeout.
It’s all done through this AppleScript I assembled from snippets at OSX Hints and Doug’s AppleScripts, plus some experimentation. I mapped it to the F13 key using the no-longer-available LumaCode Key Xing, but it should work fine from other AppleScript launchers.
Launch the script when iTunes is stopped, and you’re prompted to enter a new volume level; it defaults to the level it was at when you paused the music. iTunes will then fade in and start playing.
I’ve pasted the script below. Because it’s tough to display code examples in our narrow blog format, here’s a link to download it. Please let me know if you have suggestions.
(*
db iTunes Vol, Play, or Fade
By David Battino, Batmosphere.com
Based on ideas from Doug's AppleScripts and Mac OS Hints
This script fades out iTunes if it's playing and fades it in if it's stopped.
*)
global okflag --Update 2007-06-07: changed from "property okflag : false"
set okflag to false
set front_app to (path to frontmost application as Unicode text) -- So we can switch back to this after running the fade
-- check if iTunes is running
tell application "System Events"
if process "iTunes" exists then
set okflag to true --iTunes is running
end if
end tell
if okflag is true then
tell application "iTunes"
if (player state is playing) then
set currentvolume to the sound volume
set heyyou to "iTunes is cranked to " & currentvolume & "." & return & ¬
"Set the new volume (0-100):" --dialog message
repeat
tell application "Finder"
set dialogResult to display dialog heyyou default answer "0" with icon 1
end tell
if the text returned of dialogResult is "0" then
set savedVolume to the sound volume
--Fade down
repeat with i from savedVolume to 0 by -1 --try by -4 on slower Macs
set the sound volume to i
delay 0.01 -- Adjust this to change fadeout duration (delete this line on slower Macs)
end repeat
pause
--Restore original volume
set the sound volume to savedVolume
exit repeat
else
try
set the sound volume to text returned of dialogResult as number
exit repeat
on error
beep
set heyyou to "Please enter a number between 0 and 100."
end try
end if
end repeat
else
repeat
set dialogResult to display dialog "iTunes is stopped." & return & "The current volume is " & the sound volume & "." & return & ¬
"Begin playing at volume (1-100):" default answer "70" with icon 1
try
set the sound volume to text returned of dialogResult as number
play
exit repeat
on error
beep
end try
end repeat
end if
end tell
tell application front_app
activate
end tell
end if
UPDATE, 2007-03-05:Thanks to Gavin’s request, here’s a version that fades in and fades between values:
(*
db iTunes Vol, Play, or Fade, version 2 -- now with fade-in
By David Battino, Batmosphere.com
Based on ideas from Doug's AppleScripts and Mac OS Hints
This script fades out iTunes if it's playing and fades it in if it's stopped.
*)
global okflag --Update 2007-06-07: changed from "property okflag : false"
set okflag to false
set front_app to (path to frontmost application as Unicode text) -- So we can switch back to this after running the fade
-- check if iTunes is running
tell application "System Events"
if process "iTunes" exists then
set okflag to true --iTunes is running
end if
end tell
if okflag is true then
tell application "iTunes"
if (player state is playing) then
set currentvolume to the sound volume
set heyyou to "iTunes is cranked to " & currentvolume & "." & return & ¬
"Set the new volume (0-100):" --dialog message
repeat
tell application "Finder"
set dialogResult to display dialog heyyou default answer "0" with icon 1
end tell
if the text returned of dialogResult is "0" then
set savedVolume to the sound volume
--Fade down
repeat with i from savedVolume to 0 by -1 --try by -4 on slower Macs
set the sound volume to i
delay 0.01 -- Adjust this to change fadeout duration (delete this line on slower Macs)
end repeat
pause
--Restore original volume
set the sound volume to savedVolume
exit repeat
else
try
--make fade direction negative if target volume is lower than current volume
set fadeDirection to 1 --try 4 on slower Macs
set targetVolume to (text returned of dialogResult as number)
if targetVolume < currentvolume then
set fadeDirection to -1 --try -4 on slower Macs
end if
repeat with k from currentvolume to (text returned of dialogResult as number) by fadeDirection
set the sound volume to k
--delay 0.01 -- Adjust this to change fadeout duration (delete this line on slower Macs)
end repeat
exit repeat
on error
beep
set heyyou to "Please enter a number between 0 and 100."
end try
end if
end repeat
else
repeat
set dialogResult to display dialog "iTunes is stopped." & return & "The current volume is " & the sound volume & "." & return & ¬
"Begin playing at volume (1-100):" default answer "70" with icon 1
try
set the sound volume to 0 --2007-03-20 script update to fix startup glitch
play
repeat with j from 0 to (text returned of dialogResult as number) by 1 --try by 4 on slower Macs
set the sound volume to j
--delay 0.01 -- Adjust this to change fadeout duration (delete this line on slower Macs)
end repeat
exit repeat
on error
beep
end try
end repeat
end if
end tell
tell application front_app
activate
end tell
end if
And now what Gavin really wanted, here’s a version that simply fades in or fades out with no dialogs:
(*
db iTunes Fade-in/out
By David Battino, Batmosphere.com
Based on ideas from Doug's AppleScripts and Mac OS Hints
This script fades out iTunes if it's playing and fades it in if it's stopped.
*)
global okflag --Update 2007-06-07: changed from "property okflag : false"
set okflag to false
set front_app to (path to frontmost application as Unicode text) -- So we can switch back to this after running the fade
-- check if iTunes is running
tell application "System Events"
if process "iTunes" exists then
set okflag to true --iTunes is running
end if
end tell
if okflag is true then
tell application "iTunes"
set currentvolume to the sound volume
if (player state is playing) then
repeat
--Fade down
repeat with i from currentvolume to 0 by -1 --try by -4 on slower Macs
set the sound volume to i
delay 0.01 -- Adjust this to change fadeout duration (delete this line on slower Macs)
end repeat
pause
--Restore original volume
set the sound volume to currentvolume
exit repeat
end repeat
else
set the sound volume to 0 --2007-03-20 script update to fix startup glitch
play
repeat with j from 0 to currentvolume by 2 --try by 4 on slower Macs
set the sound volume to j
end repeat
end if
end tell
tell application front_app
activate
end tell
end if
Nice, but perhaps it would be nice if it quickly faded back the volume as well... Also, I prefer just running the script. I think it would be better to just fade to zero, pause, and when you run it again it quickly fades back to the original volume...
By "just running the script" I mean no dialogues,,.
This seems complex. Why can't you use just Quicksilver and some iTunes triggers?
@Gavin: You're right. It doesn't fade in from pause. I'll see if I can add that. The reason I offered the level-setting dialog was because sometimes I just want to change the level rather than fade out and this way one button is all I need.
Fair enough, I just prefer pressing a button to do it all. I tried editing the script to fit my purposes, but could only get it to work properly in Script Editor... I guess I'll have to assume volume to be set is some value or have a dialogue...
@Brian:
This seems complex. Why can't you use just Quicksilver and some iTunes triggers?
Does QuickSilver offer fading? The real reason to use AppleScript, of course, is to get more control and learn how the Mac works. I'm sure there's a more efficient way to code this. Perhaps someone will show us.
Well, I've edited the script to have no dialogues, just fade in and fade out... Do you want me to post it?
One question: is there any way to just end the script if iTunes isn't running? Currently, it just opens iTunes instead. I guess you might want that, but what if I accidentally press the wrong key or key combination?
@Gavin:
Well, I've edited the script to have no dialogues, just fade in and fade out... Do you want me to post it?
Sure! I added one as well.
The okflag bit is supposed to end the script if iTunes isn't running. It doesn't seem to work consistently. Anyone have a better approach?
I've found the problem, why it always launches iTunes...
On my computer, it keeps setting "okflag" to true, whether iTunes is running or not. Thus it always runs the full script. Annoying. So we'd better find some other way of testing...
I want to thank you folks for working on this. I'm not a developer, but this script will be very handy for me. If possible, I'd be most grateful for a link to the completed script that accomplishes the simple single-command fade in or fade out with no dialogs. Thanks again for your efforts. Sincerely appreciated.
I cleaned up the code a bit, and flattened it out (I can't stand this absurd deep nesting). Take a look: http://pastie.textmate.org/44906
Also note that with that version, making it just fade in/out with no dialogs is very simple to accomplish.
Gavin said:
I've found the problem, why it always launches iTunes...
On my computer, it keeps setting "okflag" to true, whether iTunes is running or not. Thus it always runs the full script. Annoying. So we'd better find some other way of testing...
Yes, the problem here is that a "property" of a script will get saved after the script is run, and so the next time you run the script it will still be true. See my pasted version above. That should fix the problem.
Also, I made a nice set of iTunes controller scripts a while ago that will show growl notifications. You can find them here. I use them with quicksilver triggers set to ⌘ + number pad keys (on laptops that is ⌘ + Fn + right half of the keyboard), and they work wonderfully. No fading in or out though.
Jacob: Thanks for sharing the property insight and cleaning up the code. You seem to have left out a play command (or playpause), though, so the script doesn't start iTunes when it's paused.
Jacob's tip to replace the property with a global variable worked.
In any of the scripts above, change
property okflag : false
to
global okflag
set okflag to false
...and the script will exit if iTunes isn't running. Here's a downloadable version of the simple Fade-in/Fade-out script Gavin and Lee wanted.
Thanks ever so much, folks.
Just for clarity (to help everyone improve), here are some things I changed from the original script:
1. When there are multiple uses of the same type of functionality, a handler is called for, so I defined a "fade" handler. This cuts out at least one, if not two, levels of nesting. In general, if a program has more than 2-3 levels of nesting, I don't like it, as it starts to scroll off the right edge of my screen.
2. The word "the" is unnecessary in applescript, though I suppose it doesn't hurt anything.
3. when testing booleans, there's no need to specify "if «bool» is true". "if «bool»" is just fine, as "«bool» is true" should evaluate to the same thing as "«bool»".
4. uses "System Events" to get GUI events, rather than Finder or iTunes, to avoid bringing those applications to the front, and then pushing them back again.
There might be some other things too. Anyway, this version should just do the simple fade in/out, without any GUI or fuss:
http://pastie.textmate.org/44996
We do something very similar here, but actually call the script via our phones.
We use Snom 360 VOIP phones which have the options to send a web request on certain actions - such as phone pick up/phone down. This way, when ever someone picks up a phone in the office, the music fades down, until the phone is put down at which point the music returns to it's previous volume.
This is a nice thought but I find most people always fight the tools apple provides for accomplishing things. A simple right-click on the dock icon and selecting "pause" is simple enough without all the key mapping, volume changing and having an applescript running all the time. Or if itunes is the frontmost application a simple push of the space bar also pauses it.
Hank:
I find most people always fight the tools apple provides for accomplishing things. A simple right-click on the dock icon and selecting "pause" is simple enough
Ah, but the journey is the reward. Look how much smarter we all are now! ;-) Also, because I keep my dock hiden, finding and Control-clicking the iTunes icon takes some concentration at a moment when I’ve just been interrupted. That’s why I prefer a key command.
Very useful code, thank you for sharing!
Is it possible for the song to fade back in with a small delay, say 1 or 2 seconds before it was faded out?
Can you please do it?
again, thank you or sharing very useful to me
I should add that when restoring sound it starts up at the highest level for a fraction of a second and then it starts fading in. It is quite an abrupt change if using headphones.
Does that happens to you as well?
@Andres: I’d be happy to refine it. But which of the three scripts are you talking about?
David, I got the script from the above comment,
"Here's a downloadable version of the simple Fade-in/Fade-out script Gavin and Lee wanted."
David Battino | March 5, 2007 05:00 PM
thank you for your time :D
@Andres: You're right — there is a small glitch when iTunes starts up again. That's because I had restored the volume to the previous value after pausing playback. Adding set the sound volume to 0 right before the play line fixes that. I'll update the code examples above.
I'm not clear what you mean by "Is it possible for the song to fade back in with a small delay, say 1 or 2 seconds before it was faded out?" Can you explain?
David, I appreciate your time, thank you.
Let's suppose you pause a song at 1:40, then the volume fades out smoothly and takes 2 seconds until volume is zero. Then when unpaused begins at 1:40 from zero volume and reaches the original volume level in 1 second. I think your code makes it begin from 1:42 and fades in until is ~1:43. What should I do to make it begin from 1:40 when fading back in?
David,
thanks for the sound volume fix, it works but only when itunes windows is not hidden. if it is hidden it brings up the sound loud. I am running the script from quick silver.
@Andres: To make iTunes back up one second before fading in, add these lines before the play command:
set pausepoint to player position
if pausepoint > 1 then
set player position to (pausepoint - 1)
end if
I had to dial the stepback number down to 0.1 before I liked the effect.
I'm not sure why QuickSilver makes the music blast back in.
Wow it works like a charm :D
Thank you for your time, Im now studying your code. I will attempt to code a script that lowers the level to certain good level immediately and then goes back smoothly to the previous volume setting. I;ll post it here to see if is useful to somebody.
again thank you
Thanks, this has been helpful. I wrote a similar thing that when used in conjunction with crontab let's my son leave his music on when he goes to bed. This turns it down and then off at night and wakes him up in the morning. Is it possible to get iTunes to stop after the current tune completes?
Eric: I saw two scripts at Doug's AppleScripts for iTunes that might be able to stop playback at the end of a song the way you want. They seem to work by copying the song to a single-song playlist.
I've been searching round for a script that can end a song on demand so that itunes will then smoothy crossfade into the next song on the playlist. Can anyone help me please? thanx!
@Ben:
I've been searching for a script that can end a song on demand so that iTunes will then smoothly crossfade into the next song on the playlist.
I don't think there's a way to trigger a crossfade in iTunes, but there are DJ programs that can do that. I did experiment with making iTunes jump to the last few seconds of the song, but that was jarring. (The Doug's AppleScripts for iTunes site has a script that jumps to X seconds before the end in a song.)
Probably the closest you could currently get in iTunes would be to fade the current song and then immediately start the next. To do that, substitute next track for pause in the third script above and adjust the fadeout time to taste. I found -10 often worked, but results vary if tracks have fades already.